Главная » Delphi, OLE, САПР » Операция «приклеивание выдавливанием» – КОМПАС в DELPHI

0

Параметры операции «приклеивание выдавливанием» (ksBossExtrusionDefinition)

Параметры операции «приклеивание выдавливанием» задаются интерфейсом ksBossExtrusionDefinition. Его возвращает метод GetDefinition() интерфейса ksEntity.

Интерфейс     ksBossExtrusionDefinition     является     полной     копией

интерфейса ksBaseExtrusionDefinition, который мы рассматривали в главе 54. Однако, не смотря на их похожесть нужно помнить о том, что это два разных интерфейса.

Пример

В качестве примера мы напишем небольшую программу, которая будет строить простой вал. На рисунке ниже показан чертеж этого вала с размерами.

Построение данной 3D-модели будет осуществляться в таком порядке.

1)                                       В плоскости XOY строится эскиз (эскиз 1), представляющий собой окружность радиусом 15 мм (30/2).

2)                                       Выполняется операция выдавливания на глубину 20.

3)                                       Создается смещенная плоскость, параллельная плоскости XOY и удаленная от нее на 20 мм.

4)                                       В смещенной плоскости создается эскиз (эскиз 2), представляющий собой окружность радиусом 10 мм (20/2).

5)                                       Выполняется операция «приклеивание выдавливанием» на глубину 50 мм (70-20).

Ниже приводится ключевой фрагмент исходного текста программы, выполняющей построение данной 3D-модели по описанному выше алгоритму.

const

pTop_Part = -1;

o3d_planeXOY = 1;

o3d_sketch  = 5;

o3d_planeOffset = 14;

o3d_baseExtrusion = 24;

o3d_bossExtrusion = 25;

etBlind  = 0;

vm_Shaded = 3;

var

kompas: KompasObject; Document3D: ksDocument3D; Part: ksPart;

EntitySketch1, EntityPlaneXOY, EntityExtrusion: ksEntity;

EntityPlaneOffset, EntitySketch2, EntityBossExtrusion: ksEntity; SketchDefinition: ksSketchDefinition;

Document2D : ksDocument2D;

BaseExtrusionDefinition: ksBaseExtrusionDefinition; PlaneOffsetDefinition: ksPlaneOffsetDefinition; BossExtrusionDefinition: ksBossExtrusionDefinition;

begin

//Подключаемся к КОМПАСу

kompas:=KompasObject(CreateOleObject(‘Kompas.Application.5′));

//Получаем интерфейс документа-модели

Document3D:=ksDocument3D(kompas.Document3D());

//Создаем документ-модель

Document3D.Create(FALSE,true);

//Получаем интерфейс компонента

Part:= ksPart(Document3D.GetPart(pTop_Part));

//Получаем интерфейс объекта "плоскость XOY"

EntityPlaneXOY:=ksEntity(Part.GetDefaultEntity(o3d_planeXOY));

///////////////////////////////////////////////

//Эскиз 1

///////////////////////////////////////////////

//Получаем интерфейс объекта "Эскиз"

EntitySketch1:=ksEntity(Part.NewEntity(o3d_sketch));

//Получаем интерфейс параметров эскиза

SketchDefinition:=ksSketchDefinition(EntitySketch1.GetDefinition());

//Устанавливаем плоскость XOY базовой для эскиза

SketchDefinition.SetPlane(EntityPlaneXOY);

//Создаем эскиз

EntitySketch1.Create();

//Входим в режим редактирования эскиза

Document2D:=ksDocument2D(SketchDefinition.BeginEdit());

//Строим окружность

Document2D.ksCircle(0,0,15,1);

//Выходим из режима редактирования эскиза

SketchDefinition.EndEdit();

///////////////////////////////////////////////

//Операция "выдавливание"

//////////////////////////////////////////////

//Получаем интерфейс объекта "операция выдавливание"

EntityExtrusion:=ksEntity(Part.NewEntity(o3d_baseExtrusion));

//Получаем интерфейс параметров операции "выдавливание"

BaseExtrusionDefinition:= ksBaseExtrusionDefinition(EntityExtrusion.GetDefinition());

//Устанавливаем параметры операции выдавливания

BaseExtrusionDefinition.SetSideParam(TRUE,etBlind,20,0,TRUE);

//Устанавливаем эскиз операции выдавливания

BaseExtrusionDefinition.SetSketch(EntitySketch1);

//Создаем операцию выдавливания

EntityExtrusion.Create();

//////////////////////////////////////////////

//Смещенная плоскость

/////////////////////////////////////////////

//Получаем интерфейс объекта "смещенная плоскость"

EntityPlaneOffset:=ksEntity(Part.NewEntity(o3d_planeOffset));

//Получаем интерфейс параметров смещенной плоскости

PlaneOffsetDefinition:=ksPlaneOffsetDefinition(EntityPlaneOffset.GetDefinition());

//Направление смещения – прямое

PlaneOffsetDefinition.direction:=TRUE;

//Смещение

PlaneOffsetDefinition.offset := 20;

//Устанавливаем базовую плоскость

PlaneOffsetDefinition.SetPlane(EntityPlaneXOY);

//Создаем смещенную плоскость

EntityPlaneOffset.Create();

//////////////////////////////////////////////

//Эскиз 2

/////////////////////////////////////////////

//Получаем интерфейс объекта "Эскиз"

EntitySketch2:=ksEntity(Part.NewEntity(o3d_sketch));

//Получаем интерфейс параметров эскиза

SketchDefinition:=ksSketchDefinition(EntitySketch2.GetDefinition());

//Устанавливаем смещенную плоскость базовой для эскиза

SketchDefinition.SetPlane(EntityPlaneOffset);

//Создаем эскиз

EntitySketch2.Create();

//Входим в режим редактирования эскиза

Document2D:=ksDocument2D(SketchDefinition.BeginEdit());

//Строим окружность

Document2D.ksCircle(0,0,10,1);

//Выходим из режима редактирования эскиза

SketchDefinition.EndEdit();

////////////////////////////////////////////

//Приклеивание выдавливанием

///////////////////////////////////////////

//Получаем интерфейс объекта "приклеивание выдавливанием"

EntityBossExtrusion:=ksEntity(Part.NewEntity(o3d_bossExtrusion));

//Получаем интерфейс параметров операции "приклеивание выдавливанием"

BossExtrusionDefinition:=KsBossExtrusionDefinition(EntityBossExtrusion.GetDefinition());

//Устанавливаем параметры операции "приклеивание выдавливанием"

BossExtrusionDefinition.SetSideParam(TRUE, etBlind,50,0,TRUE);

//Устанавливаем эскиз для операции "приклеивание выдавливанием"

BossExtrusionDefinition.SetSketch(EntitySketch2);

//Cоздаем операцию "приклеивание выдавливанием"

EntityBossExtrusion.Create();

//Делаем плоскости невидимыми

Document3D.hideAllPlanes:=TRUE;

//Устанавливаем полутоновое изображение модели

Document3D.drawMode:=vm_Shaded;

//Включаем отображение каркаса

Document3D.shadedWireframe:=TRUE;

//Делаем КОМПАС видимым

kompas.Visible:=true;

end;

На рисунке ниже показан результат работы этой программы.

Источник: Норсеев Сергей, «РАЗРАБОТКА ПРИЛОЖЕНИЙ ПОД КОМПАС В DELPHI»

По теме:

  • Комментарии